expected_obs_from.stan

Go to the documentation of this file.

 
vector expected_obs_from_index(
  int i, array[] vector imp_obs,
  array[,] int rdlurd, vector srdlh,
  matrix refp_lh, array[] int dpmfs, int ref_p,
  int rep_h, int ref_as_p, int g, int t, int l,
  vector refnp_lh, int ref_np, int p,
  int rep_agg_p,
  array[,,] int rep_agg_n_selected,
  array[,,,] int rep_agg_selected_idx
) {
  // Combine logit hazards from reference and reporting time effects
  vector[l] lh;
  profile("model_likelihood_hazard_allocations") {
    lh = combine_logit_hazards(
      i, rdlurd, srdlh, refp_lh, dpmfs, ref_p, rep_h, g, t, l, refnp_lh, ref_np, p
    );
  }
  // Only allocate aggregation index buffers when reporting-probability
  // aggregation is active. The l x l int array can dominate per-snapshot
  // allocation otherwise.
  array[rep_agg_p ? l : 0] int n_sel;
  array[rep_agg_p ? l : 0, rep_agg_p ? l : 0] int sel_idx;
  if (rep_agg_p == 1) {
    n_sel = rep_agg_n_selected[g, t, 1:l];
    sel_idx = rep_agg_selected_idx[g, t, 1:l, 1:l];
  }
  // Combine expected final obs and time effects to get expected obs
  return expected_obs(imp_obs[g][t], lh, l, ref_as_p, rep_agg_p, n_sel, sel_idx);
}
 
vector expected_obs_from_snaps(
  int start, int end, array[] vector imp_obs,
  array[,] int rdlurd, vector srdlh,
  matrix refp_lh, array[] int dpmfs,
  int ref_p, int rep_h, int ref_as_p,
  array[] int sl, array[] int csl,
  array[] int sg, array[] int st, int n,
  vector refnp_lh, int ref_np, array[] int sdmax,
  array[] int csdmax, int rep_agg_p,
  array[,,] int rep_agg_n_selected,
  array[,,,] int rep_agg_selected_idx
) {
  vector[n] log_exp_obs;
  int ssnap = 1;
  int esnap = 0;
  int l;
 
  // Retrospective mode: no delay or report effects. The delay distribution
  // is a point mass on slot 0, so expected observations equal the latent
  // count directly. R-side guards ensure this path is only reachable with
  // max_delay = 1, so sl[i] == 1 for every snapshot and log_exp_obs has
  // length end - start + 1.
  if (ref_p == 0 && ref_np == 0 && rep_h == 0) {
    for (i in start:end) {
      log_exp_obs[i - start + 1] = imp_obs[sg[i], st[i]];
    }
    return(log_exp_obs);
  }
 
  for (i in start:end) {
    l = sl[i];
    profile("expected_obs_from_index") {
    if (l) {
      esnap += l;
      log_exp_obs[ssnap:esnap] = expected_obs_from_index(
        i, imp_obs, rdlurd, srdlh, refp_lh, dpmfs, ref_p, rep_h, ref_as_p,
        sg[i], st[i], l, refnp_lh, ref_np, csdmax[i] - sdmax[i] + 1,
        rep_agg_p, rep_agg_n_selected, rep_agg_selected_idx
      );
      ssnap += l;
    }
    }
  }
  return(log_exp_obs);
}