combine_effects.stan

Go to the documentation of this file.

 
vector combine_effects(array[] real intercept, vector beta, 
                       int nobs, int neffs,
                       // Dense matrix components
                       matrix fdesign,
                       // Sparse matrix components
                       tuple(vector, array[] int, array[] int) sparse,
                       vector beta_sd, 
                       // Dense matrix for random effects
                       matrix rdesign,
                       int add_intercept, int sparse_design) {
  if (neffs) {
    vector[1 + num_elements(beta_sd)] ext_beta_sd = append_row(1.0, beta_sd);
    vector[nobs] result;
    vector[neffs] scaled_beta = beta .* (rdesign * ext_beta_sd);
    
    if (sparse_design) {
      // Extract sparse matrix components from fdesign
      result = csr_matrix_times_vector(
        nobs, neffs, sparse.1, sparse.2, sparse.3, scaled_beta
      );
    } else {
      result = fdesign * scaled_beta;
    }
    
    if (add_intercept) {
      result = result + intercept[1];
    }
    return(result);
  } else {
    return(rep_vector(intercept[1], nobs));
  }
}